Creamos un nuevo documento de Flash y Actionscript 3, lo ponemosa 24Frames/seg y con un ancho de 480 y un alto de 200, ahora nos descargamos estas imagenes de prueba que usaremos para nuestro ejemplo, una ves descargas (y descomprimidas) simplemente las arrastramos de la carpeta al escenario de flash… Y ahora procederemos a ordenarlas tomamos de una por una y las colocamos cada una a 10px de separacion entre ellas… (Pueden colocar una en X=0 Y=0, la siguiente en X=110 y Y=0 y luego X=220 y asi sucesivamente) una ves ordenadas las seleccionamos todas y las convertimos en MovieClip precionando F8, selecionamos el punto de control en el centro y ponemos como nombre img_mc….

Imagenes Seleccionadas Y MovieClip

Una ves echo esto, seleccionamos el MC en el escenario y en el panel de propiedades le ponemsocomo nombre de instancia “img_mc”, por ultimo colocamos el MC centrado (x=240 y=100)… Listo tenemos el MC preparado empecemos con el codigo, que solo son unas cuantas lineas, seleccionamos el primer frame de la pelicula y en el panel de acciones (F9) ponemos el siguiente codigo:

var minX:Number=35;
var maxX:Number=445;
var mitadEscenario:Number=240;
img_mc.addEventListener(Event.ENTER_FRAME,mover);

Explicacion: Es muy simple, creamos 3 Variables que contienen datos sencillos, la coordenada menor (minX) que el mc img_mc puede tener, la coordenada mayor (estas dos las sacamos simplemente haciendo que el mc quede 10px separado del inio y 10 del final del escenario) y la mitad del escenario…
Luego al MC img_mc le colocamos un listener que ejecutara la funcion “mover” cada ves que se haga el evento ENTER_FRAME…

Ahora nos falta crear esa funcion “mover” que como su nombre lo dice se encargara de mover el MC img_mc.. asi que agregamos estas lineas debajo de las anteriores:

function mover(e:Event){
	var movX:Number= ((stage.mouseX-mitadEscenario)/mitadEscenario)*15;
	img_mc.x+=movX;
	if(img_mc.x<minX){
		img_mc.x=minX;
	}else if(img_mc.x>maxX){
		img_mc.x=maxX;
	}
}

Explicacion: Primero obtenemos un valor que seran los pixeles que se movera el MC, para esto usamos una simple formula (stage.mousex: nos da la pocicion del Mouse en la coordenada X del escenario) y la mejor manera de explicarla seria con un ejemplo: Si tenemos el mouse en la coordenada 20, (stage.mouseX-mitadEscenario) nos dara como resultado -220 (esta parte siempre nos dara un numero entre -240 y 240, dependiendo la pociocion del Mouse), ahora si ese -220 lo dividimo entre la mitad del escenario -220/240 nos dara como resultado -.91 (igualmente al hacer esta division siempre obtendremos un numero entre -1 y 1, dependiendo de la pocicion del mouse!!!! =O…) por ultimo este numero lo multiplicamos por 15 (podria ser caulquier valor) y de esta forma obtenemos un movimiento de pixeles de -13.75 (simepre obtendremos un numero entre -15 y 15)… como ven de esta forma dependiendo la pociccion del mouse, la galeria se movera mas o menos rapido y en la direccion correcta!!!.. =)
Ya teniendo este valor!! se lo sumamos al valor actual de “img_mc” y asi se movera…
Por ultimo tenemos 2 condiciones que simplemente verifican si la pocicion de “img_mc” se sale de alguno de los limites que establecimos antes (minX o maxX) y si es asi entonces lo pociciona directamente en el limite…

Y listo!! tenemos nuestra galeria funcionando facilmente!! pocas lineas de codigo y da un muy buen efecto! esto en ActionScript3 =)…

Espero les haya gustado el tutorial y ya saben que cualquier duda comentario o sugerencia escribanos y estare atento =)!!!..
La proxima ves veremos como hacerla con un efecto 3D … Gracias y suerte!!

Empecemos, Primero crearemos dos nuevos MovieClips, sencillo dibujamos dos cuadros seleccionamos uno y lo convertimos en MC precionando F8, les damos cualquier nombre y luego hacemos lo mismo con el otro, una ves hecho esto, les damos un nombre de instancia en el panel de propiedades (Ctrl+F3) a uno le ponemos “miClip” y al otro “miClip2“… listo tenemos dos clips!!
Ahora creamos un campo de texto de tipo Dinamico, y le ponemos como nombre de instancia “texto”, este servira pra mostrarnos que esta pasando… =)..
Ahora seleccionaremos el primer frame de la pelicula (preferiblemente el de la capa superior) y en el panel de acciones (F9) escribimos el siguiente codigo:

function arrastrar(e:Event):void{
	miClip.startDrag();
}
function soltar(e:Event):void{
	miClip.stopDrag();
}
miClip.addEventListener(MouseEvent.MOUSE_DOWN,arrastrar);
miClip.addEventListener(MouseEvent.MOUSE_UP,soltar);

Explicacion: Este codigo hace posible que el MC “miClip” se peuda arrastrar (drag&Drop), la explicacion ya esta en el tutorial de Drag y Drop…

Ahora si probamos la pelicula el MC “miClip” se podria arrastrar, pero ahora encesitamos verificar cuando este sobre el MC “miClip2″, para eso usaremos el enterFrame y hitTest.. asi que debajo del codigo anterior escribimos el siguiente codigo:

miClip.addEventListener(Event.ENTER_FRAME,checa_choque);
function checa_choque(e:Event){
	if(miClip.hitTestObject(miClip2)){
    texto.text="Ah!! Chocaron!!!";
	}else{
	texto.text="No Se Tocan =)!";
	}
}

Explicacion: Como ven añadimos un listener a “miClip” que se encargara de ejecutar la funcion “checa_choque” mientras este el evento “Enter_Frame” (que este es mientras que el clip este en escena), luego la funcion “checa_choque” verifica si el clip “miClip” esta chocando con el objeto “miClip2″ (linea 3), si es asi modifica el texto “texto” para avisarnos que esta chocando, en caso contrario… pues no indica lo contrario XD!!..

Como ven sigue siendo simple, sin embargo es un poco mas de codigo que en ActionScript 2, talves por ahora no vean muchas ventajas en AS3.. pero mientras avancemos en el nivel de programacion veremos las ventajas de ActionScript3… Espero les sea de ayuda y cualquier duda aqui estoy con gusto… dejen sus comentarios!..

Gracias y suerte!!

Creamos un nuevo documento de Flash actionscript3 (Archivo->Nuevo->Archivo De Flash (Actionscript3)), Creamos un nuevo Movieclip y en el panel de propiedades le ponemos como nombre de instancia “miClip”. Seleccionamos el primer frame de nuestra pelicula y en el panel de acciones escribimos el siguiente codigo:

function arrastrar(e:Event):void{
 miClip.startDrag();
}
function soltar(e:Event):void{
 miClip.stopDrag();
}
miClip.addEventListener(MouseEvent.MOUSE_DOWN,arrastrar);
miClip.addEventListener(MouseEvent.MOUSE_UP,soltar);

Explicacion: Añadimos 2 Listenners a “miClip” estos se encargaran de ejcutar la funcion “arrastrar” y “soltar” al precionar sobre el MC o soltar el MC respectivamente, luego con la propiedad startDrag y stopDrag hacemos que se arraste el clip miClip.

Como ven es sencillismo, si prueban ahora podran arrastar el MC, pero este codigo solo nos permitiria arrastar el MovieClip “miClip”, el siguiente tutorial de AS3 viene de Claes y Paquetes que es la parte “dura e importante” de AS3, explicare que son y como funcionan y veremos como se utilizan para reutilizar codigo (por ejemplo este mismo codigo epr oaplicado a muchos MC facilmente)..

Sigan visitandonos y opinando! q su opinion es la q cuenta!! encerio que si! xd

gracias y suerte!

Como vemos estamos viendo los eventos al precionar, soltar, pasar por encima o salir de encima… Creamos un nuevo ducumento de Flash ActionScript 3 (les pongo una imagen q seguro ni sabian que existia esa opcion =P!!!), Seleccionamos el primer fotograma y Creamos un campo de texto dinamico, le ponemos como nombre de instancia “campo” (Por suerte esto es igual para AS2 y AS3), Ahora creamos un boton dibujando un simple rectangulo lo seleccionamos y precionamos F8, seleccionamos de tipo “boton” y le ponemos un nobre cualquiera, luego lo volvemos a seleccionar ya en el escenario y en el panel de propiedades (Ctrl+F3) le ponemos como nombre de instancia “bt1_btn”… Por ahora tenemos lo mismo que si usaramos AS2 y con AS2 seleccionariamos el primer frame y usariamos el siguiente codigo para hacer una accion al precionar:

bt1_btn.onRelease=function(){
campo.text="Modificando el Texto";
}

Botones En ActionScrip 3:

Para su mala suerte!! si probaramos ahora tendriamos un error espantoso xD!.. Se acabo ese codigo tan simple y mal escrito (segun los expertos), en AS3 estamos programando orientado a objetos! (OOP)… deberemos crear objetos, y sus respectivos eventos!.. Manos a la obra!! haremos funcionar ese boton ahora mismo! (seleccionamos el primer frame de la pelicula, en AS3 ya no podemos poner acciones en los propios MC o botones…) copiamos este codigo en el panel de acciones (F9):

function alSoltar(evento:Event):void{
	campo.text="Me Soltaste!...";
}

• Explicacion: Primero Creamos una funcion “alSoltar” esta funcion tiene 1 parametro de tipo “Event” (una variable que recibira informacion sobre quien llamo a la funcion, que evento se ejecuto y algunas otras cosas mas)… y esta misma funcion regresara “void” (nada), luego vemos que modifica el campo de texto “campo” con la propeidad “.text” que para nuestra suerte no cambia en AS3…

Ahora necesitaremos hacer que la funcion se ejecute al precionar el boton, pra esto usaremos “listener” (escuchador-perseguidor-vigilador de eventos)… para esto pegamos el siguiente codigo debajo del afuncion anterior:

bt1_btn.addEventListener(MouseEvent.CLICK,alSoltar);

• Explicacion: Como ven indicamos que al boton “bt1_btn” se le añada un Listener, este listener esta pendiente de cuando se haga un Click (MouseEvent.Click) sobre el mismo, y cuando se hace el click llama a la funcion “alSoltar” del segundo parametro..

De esta forma logramos que se haga un llamdo a la funcion, como ven es mas complicado que antes, pero al usar los eventos se nos permitira tener un mejor manejo de acceso de variables al programar en OOP… Ahora ahi mas eventos que usan de igual forma que el MouseEvent.Click como son:

• MouseEvent.MOUSE_DOWN: Al Mantener precionado el raton (onPress AS2)
• MouseEvent.MOUSE_MOVE: Al mover sobre el boton (onRollOver AS2)
• MouseEvent.MOUSE_OUT: Al Salir fuera del boton (onRollOut AS2)

Se usan añadiendo varios listeners, uno para cada evento y cambiando la funcion que queramos que se ejecute!!!…Listo!..

Ahora ya que empesamos a dominar un poquito los botones veremos como seria una funcion para llamar a una URL en AS3, para esto vamos a crear primero la funcion y ya ustedes se la asignan para que se ejecute en algun evento, antes usabamos getURL AS2, ahora no la cambiaron un poquito, el codigo seria el siguiente:

function muelalab(e:Event):void{
navigateToURL(new URLRequest("http://www.muelalab.com"));
}

Explicacion: Se crea la funcion con su nombre “muelalab” y parametro de tipo “Event”,  luego se usa la funcion “navigateToURL” y a esta funcion tenemos que hacerle un pedido para llamar a una URL, lo hacemos escribiendo “new URLRequest” y dentro de esta funcion colocamos el link…

Listo!… y por que asi tan dificil?? bueno ahora usamos este  metodo que luego veremos mas ampliamente, pero en si la novedad es que podremos enviar un url con datos para formularios GET o POST, o cualquier otro tipo de informacion…

Bueno esso seria todo, espero les sea de ayuda!.. y cualquier duda/sugerencia/comentario estoy para escucharlos!… Estaremos colocando tutoriales muy seguido asi q sigan visitandonos, y recomiendenos con sus amigos xD!.. Gracias y suerte!!!…

Entonces damos el salto o no???
Yo en mi opinion recomiendo dar el salto de AS2 a AS3 si y solo si recien empiesas a usar AS2 (o nunca lo has usado), es decir no sabes muchooo o tambien si crees conocer mucho de AS2. Si estas a un nivel intermedio donde porfin comienzas a comprender AS2 no lo hagas! mejor sigue experimentando con AS2 que como te digo es igualmente poderoso (amenos que haga un codigo muy complejo!! talves se note la diferencia de algunos segundos), y luego cuando lo comprendas mejor haces el salto (y veras q no es tan dificil).

Que pasa?? cual es la diferencia??

Diferencias AS3 y AS2:

• La principal diferencia es que ActionScript 3 esta mucho mas orientado a objetos (OOP), que si nos da un mejor rendimiento, pero es necesario el manejo de Clases y Objetos (que te complica un poco si no esta familiarisado con ellos). Mientras que en AS2 no es necesario el manejo de estos, y en realidad es mucho mas sencillo.
• Muchas funciones o palabras claves se cambiaron para AS3 otras se eliminarion, porsupuesto que no es lo mismo programar en AS2 y AS3 pero es como pasar de C a C++, aqui tienen un enlace que les da referencia a las nuevas funciones y metodos de AS3
• AS3 Ideal para utilizar Flex 2.0 o posterior
• AS3 corre bajo la nueva maquina virtual de ActionScript AVM2 que le da un rendimiento hasta 10veces mayor.

Como ven aunque yo apoyo AS2 la puntuacion a favor la tiene AS3, sin embargo repito una vez mas, aun hoy en dia empresas de diseño grandes utilizan AS2 el por que es simple, AS2 es facil y eficiente, suficientemente poderoso como para crear juegos (y muy buenos!), no se queda atras de AS3. Lo que si es que no podemos escapar de la tecnologia y los avanzes y AS3 es el avance… Por lo tanto has el salto!! lo antes posible… pero solo cuando te sientas preparado aun no hay apuro.

Bueno espero les ayude a formarse una opinion y como les digo yo seguire escribiendo de AS2, pero agregare AS3, asi que quienes quieran hacer el salto, peuden dejarme sus dudas/comentarios o si queiren que les ayude a migrar un codigo de AS2 a AS3 y con gusto estare por aca ayudandoles con su problema =)…

Gracias y suerte!!!

Esto se logra haciendo una conexion entre el swf y facebook (php) parecida a la conexion entre dos SWF

Empesemos con el Flash:
Abrimos un nuevo documento de Flash ActionScript2, seleccionamos el primer frame y en el panel de acciones (F9) pegamos este codigo:

conexion = new LocalConnection();
nombreConexion = _root.fb_local_connection;
function callFBJS(){
if(nombreConexion){
conexion.send(nombreConexion, "callFBJS", "publicarMensaje", ["Muelalab.com"]);
}}
callFBJS();

Explicacion:
Creamos una nueva conexion Local en la variable “conexion”, en la variable “nombreConexion” guardamos el nombre de la conexion siempre tendra que ser “_root.fb_local_connection;”, este es el nombre de la conexion hacia facebook y siempre sera asi… Luego se crea una funcion “callFBJS” (tambien esta siempre se debera llamar asi), aqui simplemente hacemos una verificacion para checar que se haya logrado hacer la conexion y si es asi entonces envia (.send) algunos parametros, los primeros 2 siempre deberan ser el nombre de la conexion y el tipo “callFBJS” (vamos a hacer una llamada a una funcion FBJS), el tercer parametro es el nombre de la funcion FBJS que ejecutaremos en nuestro csaso la llamamos “publicarMensaje” y por ultimo un array con los datos que queramos enviar, en nuestro ejemplo enviaremos “Muelalab.com”.. listo! ese es todo el SWF, ahora vamos por el php…

Ahora el PHP:
Creamos un nuevo archivo php, y vamo a colocar el siguiente codigo:

<fb:fbjs-bridge/>
<fb:swf
	swfsrc='http://muelalab.com/facebook/tutos/flash1/flashfacebook1.swf'
	width='400' height='120' />
<script>
function publicarMensaje(valor){
var mensaje='Mensaje De Prueba: ';
var mostrar = mensaje+valor;
Facebook.streamPublish(mostrar);
}
</script>

Explicacion:
Se crea un puente (conexion) entre Flash y facebook usando el tag FBML “” esto permite enviar y recibir datos desde flash, este puente siempre se debe colocar antes de insertar el swf,  luego insertamos el swf de la manera mas simple, solomente indicando la ruta del swf y el tamaño en largo y ancho… si probaramos ahora veriamos el swf, pero solo eso… Entonces creamos la funcion FBJS (Facebook JavaScript) esta funcion tiene como nombre el que indicamos en el swf en el tercer parametro “publicarMensaje” (ooh ya entienden? xD), y recibe como parametros en la varible “valor” los valores que le haymos enviado en el 4to parametro… y simplemente usando la funcion “streamPublish” de FBJS hacemos que muestre el cuadro de publicacion con el mensaje recibido desde Flash (valor) =)…

Listo, recuerden que para probar esto deben configurar la aplicacion facebook, que sea de tipo “Canvas” y pues logicamente poner la ruta de sus archivos… subir los archivos a su servidor y probar =)… (les deje el ejemplo de como se ve al inicio del post)…

Bueno espero q esto les sea de ayuda y saben que estoy atento a todos sus comentarios! asi que no duden en escribirme..

Gracias y suerte!!!!!!….

Su uso es muy variado, lo vemos comunmente en juegos donde se nos indica que se estan cargando las texturas y al finalizar la carga, no indica que se estan cargando ahora los puntuajes, etc etc.. y cuando finaliza de cargar todo es cuando da inicio al juego (es solo un ejemplo).. Y Bueno de la vista nace el amor, aqui esta el ejemplo (notese que comienza a cargar cada una de las imagenes, y al final nos indica que esta todo listo):

Bueno vamos a hacerlo…:

Abrimos un nuevo documento de Flash (AS2), creamos un nuevo MC vacio (Ctrl+f8)  y lo llamos contenedor, esto nos llevara a la linea de tiempo de este MC, asi que regresamos a la linea de tiempo principal (escena1), ahora arrasttrramos de la biblioteca (Ctrl+L) 4 veces el mc “contenedor” al escenario, seleccionamos uno y en el panel de propiedades (Ctrl+F3) le ponemos como nombre de instancia “cargando”, luego seleccionamos otro mc y ponemos como nombre de instancia “con0″, al otro “con1″ y otro “con2″, estos ultimos los usaremos para cargar ahi las imagenes, y el primero para que verifique la carga. Ahora creamos un campo de texto de tipo dinamico con nombre de instancia “carga_txt”. Ahora abrimos el panel de acciones (F9) y escribimos el siguiente codigo:

banner=["b1.jpg","b2.jpg","b3.jpg"];
carga=-1;
function precarga(){
	carga++;
if(banner[carga]!=undefined){
	mc=eval("con"+carga);
	mc.loadMovie(banner[carga]);
	_root.cargando.onEnterFrame=function(){
		bt=mc.getBytesTotal();
		bl=mc.getBytesLoaded();
		_root.carga_txt.text="("+banner[_root.carga]+")  -  ";
		_root.carga_txt.text+=Math.round(bl/1024)+"Kb / "+Math.round(bt/1024)+"Kb";
		if(bt>4000 && bl>=bt){
			delete this.onEnterFrame;
			_root.precarga();
		}
	}
}else{
_root.carga_txt.text="Se Ha Cargado Todo";
}
}

Como Funciona:
Primero definimos un array “banner”, este array contendra todos los nombres de lso archivos que se vana a cargar, de 1 a ilimitado… lo nombres pueden ser cualquier cosa no es necesario que se parescan (como en mi ejemplo), simplemente se escribe el nombre del archivo entre comillas, separados por comas. Pueden ser (.jpg .swf .png etc)..
Luego se define una variable “carga” en -1, enseguida tenemos una funcion “precarga” esta funcion es la que debemos llamar para comenzar la precarga, vamosa explicarla:

Al ser llamada aumenta la variable carga (carga++), de -1 pasa a 0, se hace una condicion que verifica si el elemento “carga” de “banner” es diferente de undefined, esto es para verificar que aun haya elementos en el array, por ejemplo si carga esta en 0 banner[carga] sera igual a banner[0] osea a “b1.jpg” por lo tanto no es undefined (que no exite el elemento), mientras haya elementos entra en esa condicionm luego usamos la funcion “eval” esta funcion le mandamos la expresion “con”+carga, lo que hace eval es guardar en la variable “mc” la ruta de “con0″ (en caso de que nuestra variable carga este en 0), asi ahora podemos usar “mc” para referirnos al “con0″ y ahi cargar la imagen 0.
La linea 7 usa la funcion loadMovie para cargar el elemento actual (“b1.jpg”), luego mientras el mc “cargando este en el escenario se ejecutara una funcion, esta funcion obtiene los bytescargados (bl) y lso bytestotales (bt) que hay actualmente en el “mc” (con0), luego meustra en el campo de texto el nombre del archivo seguido de los Kb cargados y totales (dividimos bl y bt entre 1024 por que 1Kb equivale a 1024bytes, y las variables bl y bt estan en bytes)…

Despues en la linea 13 se hace uan verificacion, se verifica que el archivo pese mas de 4Kb (esto no seria necesario, pero se lso recomeindo ponr siempre), y luego lo importante.. verifica si los bytescargaos son mayores o iguales a los bytestotales (bl>=bt) es decir que ya se haya cargado el archivo… si la condicion es cierta (se ha cargado el archivo) detiene el enterframe (delete) para que ya sno se ejecute mas, y simplemente vuelkve a llamar a la funcion precarga(), asi de esta forma al volver a llamar la funcion la funcion suma 1 a carga, y ahroa tenedremos el sigueinte contenedor “con1″ y el siguiente elemento “b2.jpg” =)!!!… y se ahra la carga de ese archivo en ese contenedor.. por ultimo si se llama a la funcion precarga, pero ya no ahi mas archivos (lo que verificamos en la linea 5), entonces se nos muestra un mensaje diciendo que los archivos han sido cargados completamente (aqui se podrian poner otras acciones, como empesar el juego por ejemplo )

Y es todo! hemos terminado… Espero que haya quedado muy claro, recuerde que igual peuden descargarse lso archivos para que puedan ver perfectamente como esta hecho… saben que si tiene dudas/comentarios/sugenrencias y/o agradecimientos, pueden dejar su comentario que la verdad es muiy importante para mi…

Gracias y suerte!!

Como ven, en este ejemplo les doy una lista de productos, con su precios y tu como usuario puedes seleecionar los productos q deses y al precionar pagar te da el precio total a pagar..
Bueno pues empecemos:
Abrimos un Nuevo Documento en Flash, y vamos a prepar los obejtos, empesaremos colocando los CheckBox, para esto abrimos los componentes (Ctrl+F7) o en Ventana->Componentes…
Una ves ahi arrastraremos el componente “CheckBox” al escenario, ahora nos aparecera en la biblioteca (Ctrl+L) y en el escenario..
Vamos a seleccionarlo en el escenario y en el panel de propiedades (Ctrl+F3), cambiaremos el nombre de instancia a “c0″.
Ahora abrimos el “inspector de componentes” (Mayus+F7) o Ventana->Inspector de componentes, y en la pestaña parametros, tenemos 3 valores, el primero es “Value” este es el texto que mostrara, aqui colocaremos “Manzana – $10″, luego tenemos “LabelPlacement”, esto es la pocicion del texto, en mi caso la tengo a la derecha (right) y por ultimo tenemos “selected” este nos permite mostrar el checkbox selecionado o no seleccionado al inicio. Lo dejamos en False.

Bueno ya tenemos un checkbox listo, ahora lo seleccionamos y copiamos, y pegamos XD!, para tener 4 en el escenario, a cda uno hagan el proceso de cambiar el “Value” en lso parametros por lo q gusten.. y cambiar el nombre de instancia a “c1″,”c2″,”c3″ (es decir cada checkbox tendra el nombre de instancia diferente, por el numero, asi tendremos del c0 al c3)

Listo!? Bueno ya casi acabamos ee! Ahoracreamos un boton, para el ejemplo no tiene q ser bonito XD!, dibujan un rectangulo, lo seleccionan y precionan F8, ahi seleccionan tipo “boton” y dan aceptar… seleccionan el boton y en el panel de propeidades (Ctrl+F3) le ponen como nombre de instancia “miboton”.. Ahora creamos un campo de texto, y en el panel de propeidades lo cambiamos aa tipo “dinamico” y ponemso como nombre de instancia “total”.

Ahora si, veremos el codigo.. Seleccionamos el primer frame de nustra pelicula y en el panel de acciones (Ctrl+F3) escribimos el siguiente codigo:

precios=[10,8,12,15];
miboton.onRelease=function(){
precio=0;
for(a=0;a<=3;a++){
box=eval("c"+a);
if(box.selected==true){
precio+=precios[a];}}
total.text="$"+precio;}

Explicacion: Creamosun array "precios", con los precios que queramos (podria ser palabras o frases en caso de algun otro tipo de lista), estos valores corresponden a los checkbox, el 10 corresponde al c0, el 8 al c1 y asi respectivamente...
Luego se crea una funcion que se ejecutara al precionar (onRelease) "miboton", en esta funciono tenemos un variable "precio=0" que nos servira para llevar la cuenta, luergo iniciamos un for, el for es un ciclo que en este caso iniciara en 0 (a=0) y se ejecutara mientras a<=3, cada ciclo a "a" se le aumenta 1 (++).... (lso for son lo mas comun en programacion deberian conocerlos, si no!, avisenem y hago un tutorial de fors XD)
Luego en cada ciclo, a la variable "box" le asignaremos la ruta del checkbox actual, lo ahcemos con "eval" y luego le pasamos el nombre de instancia ("c"+a), como a empiesa valiendo 0 seria "c0", al sigueiten ciclo "a" valdra 1, asi q sera "c1" y asi sucecivamente hasta q a sea menor o igual a 3, y asi se acabaran lso ciclos.
Ahora con uan condicion "if" y la propiedad "selected" hacemos una comparacion, Si box esta seleccionada (selected==true), entonces a lavariable precio le sumaremos el valor correspondiente.. esto lo hacemos obteneidno del array "precios" el valor "a" q como dijimos si a=0 entonces sera el 10, si es 1 sera el 8, etc....
De esta forma en cada ciclo se hace la condicion con el checkbox correspondiente... ssi esta seleccionado se le suma el costo en la variable "precio".. Por ultimo al terminar el For, se muestra en el campo de texto "total" el signo "$" seguido del precio que se obtuvo..

Listo!! XD, echenle cabeza en realidad es muy sencillo, si probamos la pelicula! Ctrl+Enter, podremos ver como funcionan nuestro ejemplo ...
Espero q les sea de ayuda! y ya saben q cualquier duda, comentario.. PORFAVOR! XD no duden en escribirnolo.... Recuerden q igualmente les deje los archivo del ejemplo, apra q puedan checarlos..
Suerte y sigan visitandonos!...

En realidad su uso es muy sencillo.. y pues aqui les dejo un ejemplo:
envia_lc

recibe_lc

Empesemos, vamos a crear dos nuevos documentos FLA que usaremos para enviar datos y otro para recibirlos (igualmente se pueden enviar y recibir datos en el mismo swf).
Primero haremos el enviar datos (envia_lc).
Seleecionamos el primer frame de este fla, y en el panel de acciones (F9), escribimos el siguiente codigo:

_root.envia_lc = new LocalConnection();
_root.envia_lc.send("recibe_lc","mostrar", "Texto que enviaremos");

Explicacion: mas que sencillo xd… creamos una variable en el _root (linea de tiempo principal) que llamamos “envia_lc” y en esta variable creamos una nueva clase localConnection. Luego en la segunda linea, usamos el metodo send (enviar) sobre la variable “envia_lc” de localConnection, que nos pide 3 parametros. Nos pide el nombre de la conexion que debe buscar (recibe_lc) que esta la crearemos en el otro archivo fla, luego nos pide la funcion que se ejecutara (“mostrar”) y por ultimo un tercer parametro que sera opcional “Texto que enviaremos”, y es un dato que recivira la funcion “mostrar”…

Bueno eso seria todo en el archivo envia_lc, ahora crearemos el archivo “recibe_lc”
En este archivo fla, crearemos la conexion que sera la que busca el archivo “envia_lc”, Primer en el primer frame creamos un campo de texto de tipo dinamico que llamaremos “texto_txt”, luego seleccionamos el primer frame y en el panel de acciones (F9) escribimos le sigueitne codigo:

recibe_lc = new LocalConnection();
recibe_lc.mostrar = function(datos){
_root.texto_txt.text=datos;}
recibe_lc.connect("recibe_lc");

Explicacion: se crea uan variable “recibe_lc” de tipo localConnection… ahora a esta variable le asignamos una funcion “mostrar” (que es la funcion que mandamos ejecutar en el archivo “envia_lc”, como ven este funcion va a recibir “datos” (que es el tercer parametro del archivo “envia_lc”), y la accion que ejecuta esta funcion es mostrar “datos” en el campo de texto “texto_txt”.
Por ultimo se realiza la conexion, con el metodo “connect” que nos pide un nombre para la conexion que en este caso le puse “recibe_lc” (este es el que debe ir en el primer parametro de la funcion “envia_lc”)..

Y como ven ya todo quedo enlazado, ahora abrimso ambos (Ctrl+Enter) y veremos que el texto se envia y se muestra en “recibe_lc”.. (Ahi que abrir primero el archivo “recibe_lc”)
Por ultimo pra que funcione con botones, es simplemente colocando el metodo send, del archivo “envia_lc” dentro de las acciones de un boton, pro ejemplo asi:

on(release){
_root.envia_lc.send("recibe_lc","mostrar", "Datos a enviar");}

Se puede enviar tantos datos como queramos, si quedan con dudas pues saben que siempre les dejo el codigo fuente, descarguenlo y revisenlo…
Espero les sea de ayuda! y pues sigan visitandonos!
Felizes Dias! ^^

Bueno el codigo es sencillo, se coloca en la linea de tiempo principal, y es el siguiente:

Stage.scaleMode="noScale";
function cambiar(){
if(Stage.displayState=="normal"){
Stage.displayState="fullScreen";
}else{Stage.displayState="normal";}}

Explicacion: Bueno primero como les decia ajustamos la escala del escenario a “noScale” (sin escala), luego tenemos funcion que llamamos “cambiar” en esta ahi una condicion, SI se esta visualizando (Stage.displayState) es Igual a “normal”, entonces lo cambia a “fullscreen” (pantalla completa), SI NO (else) entonces lo cambia la pantalla a “normal”

Entonces para cambiar la pantalla solo debemos llamr a la funcion, pra esto por ejemplo desde un boton la llamariamos de esta forma:

on(release){
_root.cambiar();}

Aqui simplemente llamamos a la funcion, que se encarga de cambiar la vista de pantalla..
Por utlimo deben ajustar una opcion en el flash, dan click en el Escenario y se van al panel de propiedades (Ctrl+F3) ahi seleccionan cinfiguracion, y en la pestaña HTML, cambian el valor de “Dimensiones” a porcentajae y los porcentajes los ponen en 100% ambos…

Esto seria todo ahora pueden probar su swf (tienen que probarlo desde la PC o en la web) y listo deberia funcionar!..
Espero les ayude! y nos estamos viendo! Suerte ^^!!